***
*     gugeom01.f
***
*
      SUBROUTINE UGEOM
*
***********************************************************************
*                                                                     *
*             User routine to define geometry of detector             *
*                                                                     *
***********************************************************************
C
      COMMON/GCVOLU/NLEVEL,NAMES(15),NUMBER(15),
     +LVOLUM(15),LINDEX(15),INFROM,NLEVMX,NLDEV(15),LINMX(15),
     +GTRAN(3,15),GRMAT(10,15),GONLY(15),GLX(3)
      CHARACTER*4 NAMES
C
      INTEGER IVOLU,IFIELD
C
      REAL VMOTH(3)/4000.,2000.,4000./,
     +     VTOFS(3)/200.,100.,0.75/,      ! vector of TOF (BOX)
     +     VEMCL(3)/200.,100.,40./        ! vector of EMcal (BOX)
C
      REAL FIELDM,TMAXFD,DMAXMS,DEEMAX,EPSIL,STMIN,UBUF(3)
C
*     ----------------------------------------------------------
***
*
*             Define material
*
csn.. Stores the constants for the material IMATE in the data
csn.. structire JMATE
csn..
csn.. GSMATE(IMATE,CHNAMA,A,Z,DENS,RADL,ABSL,UBUF,NWBUF)
csn..
csn.. IMATE: material number
csn.. CHNAMA: material name
csn.. A: atomic weight
csn.. Z: atomic number
csn.. DENS: density in g/cm*3
csn.. RADL: radiation length in cm
csn.. ABSL: absorption length in cm (ignored)
csn.. UBUF: array of NWBUF additional user parameters
csn.. NWBUF: number of user words in UBUF
*
      CALL GSMATE(101,'Scintillator $',6.670,3.60,1.18,
     +     34.4,70.8,UBUF,3)    ! define Scintillating material for TOF
***
*
*             Define tracking medium
*
      IFIELD=0   !no magnetic field
      FIELDM=0.  !maximum field value(Kilogauss)
      TMAXFD=5.00!maximum angle due to field permitted in one step(in degree)
      DMAXMS=0.1 !maximum displacement for multiple scattering in one step(cm)
      DEEMAX=0.1 !maximum fractional energy loss in one step
      EPSIL=0.1  !tracking precision(cm)
      STMIN=1.0  !minimum step due to energy loss or multiple scattering(cm)
*
csn.. assoiates a set of tracking parameters to a material, defining a
csn.. so-called tracking medium. The routine stores the parameters of the
csn.. tracking medium ITMED in the data structure JTMED.
csn..
csn.. GSTMED(ITMED,NATMED,NMAT,ISVOL,IFIELD,FIELDM,TMAXFD,STEMAX,
csn..        DEEMAX,EPSIL,STMIN,UBUF,NWBUF)
csn..
csn.. ITMED: tracking medium number
csn.. NATMED: tracking medium name
csn.. NMAT: material number corresponding to ITMED
csn.. ISVOL: sensitivity flag (<=0 not a sensitive volume)
csn.. IFIELD: magnetic field flag
csn.. 0=no magnetic, 1=strongly inhomogeneous,2=inhomogeneous, 3=uniform)
csn.. FIELDM: maximum fiedl value in Kilogauss
csn.. TMAXFD: max angu deviation due to the mag. field permitted in one step
csn.. STEMAX: maximum step permitted (cm)
csn.. DEFMAX: maximum fractional energy loss in one step (0<DEFMAX<=1)
csn.. EPSIL: boundary crossing precision (cm)
csn.. STMIN: minimum value for the maximum step imposed by energy loss,etc (cm)
csn.. UBUF: array of NWBUF additional user parameters
csn.. NWBUF: number of additional user parameters
*
      CALL GSTMED(1,'Air $',15,0,IFIELD,FIELDM,TMAXFD,DMAXMS,
     +            DEEMAX,EPSIL,STMIN,UBUF,3)
      CALL GSTMED(2,'Scintillator $',101,0,IFIELD,FIELDM,TMAXFD,DMAXMS,
     +            DEEMAX,EPSIL,STMIN,UBUF,3)
      CALL GSTMED(3,'Lead $',13,0,IFIELD,FIELDM,TMAXFD,DMAXMS,
     +            DEEMAX,EPSIL,STMIN,UBUF,3)
***
*
*             Define relation between axis
*
csn.. Stores rotaion matrix IROT in the data structure JROTM.
csn..
csn.. CSROTM(IROT,THETA1,PHI1,THETA2,PHI2,THETA3,PHI3)
csn..
csn.. IROT: number of the rotation matrix
csn.. THETA1(2/3): polar angle for the exis x(y/z)
csn.. PHI1(2/3): azimuthal angle for axis x(y/z)
*
      CALL GSROTM(1,90.,0.,90.,90.,0.,0.)
      CALL GSROTM(2,180.,0.,90.,90.,90.,0.)
**
*
*             Define volumes
*
csn.. Defines a volume with a given name/shape/tracking medium num/shape param
csn..
csn.. GSVOLU(CHNAME,CHSHAP,NMED,PAR,NPAR,IVOLU*)
csn..
csn.. CHNAME: char*4 volume name,  it must be unique
csn.. CHSHAP: char*4 name of one of GEANT shape
csn.. NMED: int tracking medium number for the volume.
csn.. PAR: array containing the shape parameters
csn.. NPAR: number of parameters.
csn.. IVOLU: internal volume number.
*
      CALL GSVOLU('MOTH','BOX ',1,VMOTH,3,IVOLU)
      CALL GSVOLU('TOFS','BOX ',2,VTOFS,3,IVOLU)
      CALL GSVOLU('EMCL','BOX ',3,VEMCL,3,IVOLU)
**
*
*             Position volumes
*
csn.. Places a copy of a volume previously defined by a call to GSVOLU
csn.. inside its mother volume CHMOTH.
csn..
csn.. GSPOS(CHNAME,NR,CHMOTH,X,Y,Z,IROT,CHONLY)
csn..
csn.. CHNAME: char*4 name of the volume being positioned
csn.. NR: copy number of the volume CHNAME being positioned
csn.. X/Y/Z: x/y/z position of the volume int the mother reference system
csn.. IROT: rotation matrix number describing the orientation of the vol
csn..       relative to the coordinate system of the mother
csn.. CHONLY: char*4 flag to indicate whether a point found to be in this
csn..         volume may also be in other volumes which are... (ONLY/MANY)
*
*      CALL GSPOS('',1,'MOTH',0.,0.,0.,1,'ONLY')
      CALL GSPOS('TOFS',1,'MOTH',500.,0.,0.,2,'ONLY')
      CALL GSPOS('EMCL',1,'MOTH',550.,0.,0.,2,'ONLY')
      CALL GGCLOS
      RETURN
      END
*
*